apply plugin: 'com.android.library'
apply plugin: 'com.novoda.bintray-release'

android {
  compileSdkVersion COMPILE_SDK_VERSION as int
  buildToolsVersion BUILD_TOOLS_VERSION

  defaultConfig {
    minSdkVersion MIN_SDK_VERSION as int
    targetSdkVersion TARGET_SDK_VERSION as int
    versionCode "git rev-list origin/master --count".execute().text.toInteger()
    versionName VERSION_NAME

    consumerProguardFiles 'proguard-rules.txt'
  }
}

dependencies {
  compile "com.github.bumptech.glide:glide:${GLIDE_VERSION}"
  provided "jp.co.cyberagent.android.gpuimage:gpuimage-library:${GPUIMAGE_VERSION}"
}

task androidJavadocs(type: Javadoc) {
  source = android.sourceSets.main.java.srcDirs
  classpath += project.files(android.getBootClasspath().join(File.pathSeparator))
}

task androidJavadocsJar(type: Jar, dependsOn: androidJavadocs) {
  classifier = 'javadoc'
  from androidJavadocs.destinationDir
}

task androidSourcesJar(type: Jar) {
  classifier = 'sources'
  from android.sourceSets.main.java.srcDirs
}

artifacts {
  archives androidSourcesJar
  archives androidJavadocsJar
}

publish {
  userOrg = POM_DEVELOPER_ID
  groupId = GROUP
  artifactId = ARTIFACT_ID
  publishVersion = VERSION_NAME
  desc = POM_DESCRIPTION
  website = POM_URL
}