glide-transformations/example/build.gradle

apply plugin: 'com.android.application'
apply plugin: 'kotlin-android'
apply plugin: 'kotlin-kapt'

android {
  compileSdkVersion COMPILE_SDK_VERSION as int

  defaultConfig {
    minSdkVersion MIN_SDK_VERSION as int
    targetSdkVersion TARGET_SDK_VERSION as int
    versionCode "git rev-list origin/master --count".execute().text.toInteger()
    versionName VERSION_NAME

    renderscriptTargetApi TARGET_SDK_VERSION as int
    renderscriptSupportModeEnabled true
  }

  signingConfigs {
    release {
      storeFile file(keyStoreProperty)
      keyAlias keyAliasProperty
      storePassword keyStorePasswordProperty
      keyPassword keyAliasPasswordProperty
    }
  }

  buildTypes {
    debug {
      debuggable true
      zipAlignEnabled true
    }
    release {
      debuggable false
      zipAlignEnabled true
      minifyEnabled true
      proguardFiles getDefaultProguardFile('proguard-android.txt'), 'proguard-rules.pro'
      shrinkResources true
      signingConfig signingConfigs.release
    }
  }
}

def getKeyStoreProperty() {
  return hasProperty('WASABEEF_KEYSTORE') ? WASABEEF_KEYSTORE : "debug.keystore"
}

def getKeyAliasProperty() {
  return hasProperty('WASABEEF_KEYALIAS') ? WASABEEF_KEYALIAS : "android"
}

def getKeyStorePasswordProperty() {
  return hasProperty('WASABEEF_KEYSTOREPASSWORD') ? WASABEEF_KEYSTOREPASSWORD : "androiddebugkey"
}

def getKeyAliasPasswordProperty() {
  return hasProperty('WASABEEF_KEYALIASPASSWORD') ? WASABEEF_KEYALIASPASSWORD : "android"
}

dependencies {
  implementation project(':transformations')
  implementation "org.jetbrains.kotlin:kotlin-stdlib-jdk7:$kotlin_version"
  implementation "com.github.bumptech.glide:glide:$glide_version"
  kapt "com.github.bumptech.glide:compiler:$glide_version"
  implementation "jp.co.cyberagent.android:gpuimage:$gpuimage_version"
  implementation "androidx.appcompat:appcompat:1.0.2"
  implementation "androidx.recyclerview:recyclerview:1.0.0"
  implementation 'androidx.constraintlayout:constraintlayout:1.1.3'
}